Helperlere özel mode kayıt kodu
alias help return #help
alias helper return #helper
alias helpadd writeini help.ini $1-
alias helpdel remini help.ini $1-
alias helpekle return $iif(!$ini(help.ini,$1,$2),1,$calc($readini(help.ini,$1,$2) + 1))
alias helpgoster return $iif(!$readini(help.ini,$1,$2),0,$readini(help.ini,$1,$2))
alias goster {
if ($ini(help.ini,0) == 0) { msg $helper Helperler Adina Kayit Bulunmamaktadir. | halt }
if ($1 == $null) { var %x = 1,%y = $ini(help.ini,0) | while (%x <= %y) {
msg $helper Helper: $($chr(2),$ini(help.ini,%x),$chr(2)) Voice: $+($chr(2),$helpgoster($ini(help.ini,%x),voice),$chr(2)) Devoice: $+($chr(2),$helpgoster($ini(help.ini,%x),devoice),$chr(2)) Ban: $+($chr(2),$helpgoster($ini(help.ini,%x),ban),$chr(2)) Kick: $+($chr(2),$helpgoster($ini(help.ini,%x),kick),$chr(2)) | inc %x } }
else {
if ($1 == -r) { msg $helper Helperlere Ait Butun Bilgiler Sifirlanmistir. | write -c help.ini | halt }
if ($ini(help.ini,$1) == 0) { msg $helper $1 Nickine Ait Bilgi Bulunmamaktadir! | halt }
msg $helper Helper: $($chr(2),$1,$chr(2)) Voice: $+($chr(2),$helpgoster($1,voice),$chr(2)) Devoice: $+($chr(2),$helpgoster($1,devoice),$chr(2)) Ban: $+($chr(2),$helpgoster($1,ban),$chr(2)) Kick: $+($chr(2),$helpgoster($1,kick),$chr(2))
}
}

on *:rawmode:#: {
if ($chan == $help) {
if ($1 == +v) { helpadd $nick voice $helpekle($2,voice) }
if ($1 == -v) { helpadd $nick devoice $helpekle($2,devoice) }
if ($1 == +b) { helpadd $nick ban $helpekle($2,ban) }
}
}
on *:kick:#: { if ($chan == $help) { helpadd $nick kick $helpekle($nick,kick) } }

on *:text:!bilgi*:#: {
if ($chan == $helper) {
if ($2 == $null) { goster | halt }
if ($2 == -r) { goster -r }
else { goster $2 }
}
}Kullanımı !bilgi – !bilgi nicktxt dosyasını silmek için

Bu koruma paketinin içinde Bir çok korumayı bulabilirsiniz..

Bu Korumalardan Bazıları;
- Mass Kick Koruması
- Guest Nick Koruması
- Uzun Yazı Koruması
- Join/Part Koruması
- Kontrol Kod Koruması
- Caps Koruması
- Tekrar Koruması
- Ban Koruması
- Clone Koruması
- Kötü Söz/Küfür Koruması
- Kötü Kanal Koruması
- Kanala Reklam Koruması
- Flood Koruması

Extra Olarakta URL?ye Tıklayarak URL?nin indirebilir olup olmadığını gösterecek bir kod..

Kod:
Guest Nick:
2 yolla Guest olan nickleri kickleyebiliriz. Birincisi kanala Guest nicki girdiÄŸinde, ikincisi birinin nicki Guest olduÄŸunda.

Kod:
on @*:join:#:{ if (Guest* iswm $nick) { mode # +b Guest*!*@* | kick # $nick Guest nickler giremez. } }
on *:nick:{ if (Guest* iswm $newnick) { var %] = $comchan($newnick,0) | while %] { if ($comchan($newnick,%]).op) { mode $comchan($newnick,%]) +b Guest*!*@* | kick $comchan($newnick,%]) $newnick Guest nick } | dec %] } } }

Mass Kick Koruması:
8 saniye içinde 3den fazla kişiyi kanaldan atan kişi deop edilir ve banlanır.İşte kod:

Kod:
on @!*:kick:#:{
if (!$($+(%,kicks.,$nick,.,$chan),2)) { set -u8 $+(%,kicks.,$nick,.,$chan) 1 | return }
else { inc $+(%,kicks.,$nick,.,$chan) }
if ($($+(%,kicks.,$nick,.,$chan),2) > 3) && (!%kick.check) { set -u6 %kick.check 1 | mode # -o+b $nick $wildsite | kick # $nick Mass kick! }
}

Uzun Yazı Koruması:
Kanalda op olmayan ve yazdığı yazı 300 karakterden fazla olan kanaldan atılır. [karakter sayısını kendiniz değiştirebilirsiniz.]

Kod:
on @*:text:*:#:{ if ($nick isreg #) && ($len($1-) >= 300) { ban -k $chan $nick 2 Uzun yazı! } }

Kanala Girip/Çıkanlara Ban:
Bazı insanlar kanala girip, hemen bakıp çıkar ve bu çoğu zaman sinir bozucu olur. İşte o kişileri kanaldan belirli bir süre kanaldan uzak tutmak için kod. Ben 60 saniyeye ayarladım. Değiştirebilirsiniz. [8 saniye içinde girip çıkanlara]

Kod:
on @*:join:#:{ set -u8 $+(%,door.,$wildsite,.,$chan) 1 }
on @*:part:#:{ if ($($+(%,door.,$wildsite,.,$chan),2)) { ban -u60 $chan $nick 2 } }

Kontrol Kod Koruması:
Kanalda istediğinizden fazla kontrol kodu kullananları atmak için bu kodu kullanabilirsiniz. [kontrol kodu = ctrl+k ctrl+b ctrl+u gibi..]

Kod:
on @*:text:*:#:{ if ($nick isreg #) && ($count($1-,$chr(3),$chr(31),$chr(2),$chr(15)) >= 15) { ban -ku60 $chan $nick 2 fazla kontrol kodu kullandığınız için 60 sn süreyle banlandınız. } }

Caps Koruması:
%80 oranından fazla CAPS kullananlar kanaldan atılır. Oran değerini ve ban atmayı kendiniz değiştirebilir/ekleyebilirsiniz.

Kod:
on @*:text:*:#:{ if ($calc($regex($1-,/[A-ZÀ-ÖØ-İ]/g)/$len($1-)) > 0.8) && ($len($1-) > 5) && ($nick isreg #) { kick # $nick CAPS } }

Tekrar Koruması:
5 saniye içinde 2den fazla tekrar eden ve op/voice olmayan kişiler kanaldan atılır. saniye ve tekrar sayısını kendiniz ayarlayabilirsiniz. Banlamak istersenizde değiştirebilirsiniz.

Kod:
on @*:text:*:#:{ var %m $hash($lower($strip($1-)),32),%v $+(%m,$wildsite,#) | hinc -mu5 repeat %v | if $hget(repeat,%v) = 2 { kick # $nick 5 saniye içinde 2 tekrar.. } }

Ban Koruması:
Sizi banlayan kişinin opu alınır, ban açılır. [/chanserv unban # benim-nickim komutu uygulanır.]

Kod:
on @!*:ban:#:{ if ($banmask iswm $address($me,5)) { chanserv unban # $me | mode # -o $nick | kick # $nick beni banlama } }

Clone Koruması:
Eğer kanalınıza clone girmemesini istiyorsanız aşağıdaki kodu koyun. bir IP’den sadece bir user girebilir. 1 sayısını değiştirebilirsiniz böylece 2 yada daha fazla kişi girer.

Kod:
on @*:join:#:{ if ($ialchan($wildsite,#,0) > 1) { ban -ku30 $chan $nick 9 clone! [30 saniye ban] } }

Kötü Söz/Küfür Koruması:
%badwords diye bir variable düzenliyoruz. Örneğin /set %badwords fuck,shit,dick gibi yazıyor statusde yada herhangi bir editbox’da.. Virgülle ayırıyoruz dikkat..

Kod:
on @*:text:*:#:{ if ($nick isreg #) { var %x = $numtok(%badwords,44) | while %x { if ($istok($strip($1-,$gettok(%badwords,%x,44),32)) { ban -k $chan $nick 2 küfür | return } | dec %x } } }

Kötü Kanal Koruması:
$regex($3-,/fuck|bitch|dick/i) kısmını görüyorsunuz. İstediğiniz kanalı oraya ekleyebilirsiniz. | ile ayırarak $regex($3-,/fuck|bitch|dick|bilmem|sanane|vs/i) gibi.

Kod:
on @*:join:#:{ whois $nick }
raw 319:*:{ if ($regex($3-,/fuck|bitch|dick/i)) { var %[ = $comchan($2,0) | while %[ { if ($comchan($2,%[).op) { ban -k $comchan($2,%[) $2 2 kötü kanal } | dec %[ } } }

Kanala Reklam Koruması:
Yukardaki kötü kanal koruması gibi istediğiniz reklam çeşitlerini ekleyebilirsiniz.

Kod:
on @*:text:*:#:{ if ($nick isreg #) && ($regex($1-,/http|ftp://|/server|irc.|#/i)) { ban -k $chan $nick 2 reklam yapma } }

Flood Koruması:
3 saniye içinde 5 veya daha fazla satır yazı yazan kişi kanaldan atılır.

Kod:
on @*:text:*:#:{ if ($nick isreg #) { inc -u3 $+(%,fld.,$chan,.,$nick) | if ($($+(%,fld.,$chan,.,$nick),2) >= 5) { ban -k # $nick 2 flood yapma } } }

-
Aklıma bu korumalar geldi. İstediklerinizi ekleyebilirim.
Umarım işinize yarar..

;———————————————————————-

Bu sekilde sana IRC üzerinden bir download URL si geldiginde tıklamak suretiyle indirebilirsin download edilebilir dosya formatlarını %dosya degişkenine eklemen yeterli. Sonra tek yapmangereken tıklamak..

on *:hotlink:*:*: {
.download $1 $mircdirDowload
}
on ^*&:hotlink:*:*: {
if $fle_($1) == yüklenir return
else halt
}
alias fle_ {
;bu kısma indirilebilir dosya uzantılarını ekleyebilirsin
var %dosya *.zip *.exe *.rar *.tar *.tar.gz *.gz *.vs.dosya_uzantisi
var %i 1
while $gettok(%dosya,%i,32) {
if $ifmatch iswm $1 return yüklenir
inc %i
}
}

Belirtilen nickle bulunduğunuz ortak kanalları gösteren bir kod.

alias ortak_k {
if ($server == $null) { echo -a Herhangi bir server’a bağlı değilsiniz. }
elseif ($chan($me) == 0) { echo -a Herhangi bir kanala girmiÅŸ deÄŸilsiniz. }
elseif (!$1) { echo -a Ortak kanallarınızın bulunacağı nick belirtilmedi. }
elseif ($1 == $me) { echo -a Kendi nickinizi giremezsiniz. }
elseif ($comchan($1,0) == 0) { echo -a Beliritlen nick bulunamadı. }
else {
var %oid 1
set %orka $comchan($1,0)
unset %knms
while (%oid <= %orka) {
set %knms $comchan($1,%oid) $+ $chr(32) $+ %knms
inc %oid
}
return %knms
}
}